pluginManagement {
    repositories {
        mavenLocal()
        mavenCentral {
            metadataSources {
                mavenPom()
                artifact()
                ignoreGradleMetadataRedirection()
            }
        }
        gradlePluginPortal()
    }
}

dependencyResolutionManagement {
    versionCatalogs {
        libs {
            version('gradle', '8.1.1')
            version('groovy', '3.0.15')
            version('junit', '5.9.3')
            version('datastructures', '2.3.0')
            library('junit-jupiter-api', 'org.junit.jupiter', 'junit-jupiter-api').versionRef('junit')
            library('junit-jupiter-params', 'org.junit.jupiter', 'junit-jupiter-params').versionRef('junit')
            library('junit-jupiter-engine', 'org.junit.jupiter', 'junit-jupiter-engine').versionRef('junit')
            library('hamcrest', 'org.hamcrest', 'hamcrest-library').version('2.2')
            library('datastructures-json', 'org.xbib', 'datastructures-json-tiny').versionRef('datastructures')
        }
    }
}

include 'cql-common'
include 'cql-elasticsearch'