plugins {
    id "de.marcphilipp.nexus-publish" version "0.4.0"
    id "io.codearte.nexus-staging" version "0.21.1"
}

wrapper {
    gradleVersion = "${project.property('gradle.wrapper.version')}"
    distributionType = Wrapper.DistributionType.ALL
}

ext {
    user = 'jprante'
    name = 'elx'
    description = 'Admin/Bulk/Search API extensions for Elasticsearch clients (node, transport, http)'
    inceptionYear = '2019'
    url = 'https://github.com/' + user + '/' + name
    scmUrl = 'https://github.com/' + user + '/' + name
    scmConnection = 'scm:git:git://github.com/' + user + '/' + name + '.git'
    scmDeveloperConnection = 'scm:git:ssh://git@github.com:' + user + '/' + name + '.git'
    issueManagementSystem = 'Github'
    issueManagementUrl = ext.scmUrl + '/issues'
    licenseName = 'The Apache License, Version 2.0'
    licenseUrl = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
}

subprojects {
    apply plugin: 'java-library'

    dependencies {
        testImplementation "org.apache.logging.log4j:log4j-core:${project.property('log4j.version')}"
        testImplementation "org.apache.logging.log4j:log4j-jul:${project.property('log4j.version')}"
        testImplementation "org.apache.logging.log4j:log4j-slf4j-impl:${project.property('log4j.version')}"
    }

    apply from: rootProject.file('gradle/ide/idea.gradle')
    apply from: rootProject.file('gradle/compile/java.gradle')
    apply from: rootProject.file('gradle/test/junit5.gradle')
    apply from: rootProject.file('gradle/publishing/publication.gradle')
}

apply from: rootProject.file('gradle/publishing/sonatype.gradle')