plugins {
    id 'java-gradle-plugin'
    id 'groovy'
    id 'com.gradle.plugin-publish' version '0.17.0'
}

apply plugin: 'groovy'
apply plugin: 'java-gradle-plugin'
apply plugin: 'com.gradle.plugin-publish'

dependencies {
    api gradleApi()
    api "org.xbib:groovy-git:${project.property('groovy-git.version')}"
    testImplementation gradleTestKit()
    testImplementation "org.spockframework:spock-core:${project.property('spock.version')}"
}

compileGroovy {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

compileTestGroovy {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

validatePlugins {
    failOnWarning = false
}

gradlePlugin {
    plugins {
        gitPlugin {
            id = 'org.xbib.gradle.plugin.git'
            implementationClass = 'org.xbib.gradle.plugin.git.GitPlugin'
        }
    }
}

if (project.hasProperty('gradle.publish.key')) {
    pluginBundle {
        website = 'https://github.com/jprante/groovy-git'
        vcsUrl = 'https://github.com/jprante/groovy-git.git'
        plugins {
            gitPlugin {
                id = 'org.xbib.gradle.plugin.git'
                version = project.version
                description = rootProject.ext.description
                displayName = rootProject.ext.description
                tags = ['gradle', 'plugin', 'git']
            }
        }
    }
}