guice/build.gradle

plugins {
    id "org.sonarqube" version "2.8"
    id "io.codearte.nexus-staging" version "0.21.1"
}

apply plugin: 'java'
apply plugin: 'maven'

repositories {
    mavenCentral()
}

dependencies {
    compile "org.xbib:javax-inject:${project.property('javax-inject.version')}"
    compile "org.xbib:guava:${project.property('guava.version')}"
    testCompile "org.junit.jupiter:junit-jupiter-api:${project.property('junit.version')}"
    testCompile "org.junit.jupiter:junit-jupiter-params:${project.property('junit.version')}"
    testCompile "org.junit.jupiter:junit-jupiter-engine:${project.property('junit.version')}"
    testCompile "org.junit.vintage:junit-vintage-engine:${project.property('junit.version')}"
    testCompile "junit:junit:${project.property('junit4.version')}"
    // Helper for com.google.common.testing.GcFinalization, com.google.common.testing.EqualsTester
    testCompile "com.google.guava:guava-testlib:28.1-jre"
}

compileJava {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

compileTestJava {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

tasks.withType(JavaCompile) {
    options.compilerArgs << "-Xlint:all,-fallthrough"
}

test {
    useJUnitPlatform()
    testLogging {
        showStandardStreams = false
        exceptionFormat = 'full'
    }
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier 'javadoc'
}

artifacts {
    archives sourcesJar, javadocJar
}

ext {
    user = 'xbib'
    projectName = 'guice'
    projectDescription = 'Guice for Java'
    scmUrl = 'https://github.com/xbib/guice'
    scmConnection = 'scm:git:git://github.com/xbib/guice.git'
    scmDeveloperConnection = 'scm:git:git://github.com/xbib/guice.git'
}

task sonatypeUpload(type: Upload) {
    configuration = configurations.archives
    uploadDescriptor = true
    repositories {
        if (project.hasProperty('ossrhUsername')) {
            mavenDeployer {
                beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
                repository(url: uri(ossrhReleaseUrl)) {
                    authentication(userName: ossrhUsername, password: ossrhPassword)
                }
                snapshotRepository(url: uri(ossrhSnapshotUrl)) {
                    authentication(userName: ossrhUsername, password: ossrhPassword)
                }
                pom.project {
                    groupId project.group
                    artifactId project.name
                    version project.version
                    name project.name
                    description projectDescription
                    packaging 'jar'
                    inceptionYear '2016'
                    url scmUrl
                    organization {
                        name 'xbib'
                        url 'http://xbib.org'
                    }
                    developers {
                        developer {
                            id user
                            name 'Jörg Prante'
                            email 'joergprante@gmail.com'
                            url 'https://github.com/jprante'
                        }
                    }
                    scm {
                        url scmUrl
                        connection scmConnection
                        developerConnection scmDeveloperConnection
                    }
                    licenses {
                        license {
                            name 'The Apache License, Version 2.0'
                            url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        }
                    }
                }
            }
        }
    }
}


nexusStaging {
    packageGroup = "org.xbib"
}

/*
spotbugs {
    effort = "max"
    reportLevel = "low"
}

tasks.withType(com.github.spotbugs.SpotBugsTask) {
    ignoreFailures = true
    reports {
        xml.enabled = false
        html.enabled = true
    }
}

tasks.withType(Pmd) {
    ignoreFailures = true
    reports {
        xml.enabled = true
        html.enabled = true
    }
}

tasks.withType(Checkstyle) {
    ignoreFailures = true
    reports {
        xml.enabled = true
        html.enabled = true
    }
}

pmd {
    toolVersion = '6.11.0'
    ruleSets = ['category/java/bestpractices.xml']
}

checkstyle {
    configFile = rootProject.file('config/checkstyle/checkstyle.xml')
    ignoreFailures = true
    showViolations = false
}

sonarqube {
    properties {
        property "sonar.projectName", "${project.group} ${project.name}"
        property "sonar.sourceEncoding", "UTF-8"
        property "sonar.tests", "src/test/java"
        property "sonar.scm.provider", "git"
    }
}
*/

afterEvaluate {
    compileJava {
        inputs.property("moduleName", 'org.xbib.guice')
        doFirst {
            options.compilerArgs = ['--module-path', classpath.asPath]
            classpath = files()
        }
    }
    javadoc {
        inputs.property("moduleName", 'org.xbib.guice')
        doFirst {
            options.addStringOption('Xdoclint:none', '-quiet')
            options.addStringOption('-module-path', classpath.asPath)
            classpath = files()
        }
    }
}