plugins {
    id "org.sonarqube" version "2.2"
}

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'findbugs'
apply plugin: 'pmd'
apply plugin: 'checkstyle'
apply plugin: "jacoco"

repositories {
    mavenCentral()
}

configurations {
    wagon
}

dependencies {
    compile "javax.inject:javax.inject:1"
    compile 'org.xbib:jsr-305:1.0.0'
    compile "com.google.guava:guava:21.0"
    testCompile "junit:junit:4.12"
    testCompile "org.apache.logging.log4j:log4j-slf4j-impl:2.7"
    testCompile "org.apache.logging.log4j:log4j-core:2.7"
    testCompile "javax.inject:javax.inject-tck:1"
    testCompile "com.google.guava:guava-testlib:21.0"
    wagon 'org.apache.maven.wagon:wagon-ssh-external:2.10'
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'
tasks.withType(JavaCompile) {
    options.compilerArgs << "-Xlint:all" << "-profile" << "compact1"
}

test {
    exclude '*$*'
    exclude '**/ErrorHandlingTest*'
    exclude '**/OSGiContainerTest*'
    exclude '**/ScopesTest*'
    exclude '**/TypeConversionTest*'
    testLogging {
        showStandardStreams = false
        exceptionFormat = 'full'
    }
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier 'sources'
    from sourceSets.main.allSource
}
task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier 'javadoc'
}
artifacts {
    archives sourcesJar, javadocJar
}
if (project.hasProperty('signing.keyId')) {
    signing {
        sign configurations.archives
    }
}

apply from: "${rootProject.projectDir}/gradle/ext.gradle"
apply from: "${rootProject.projectDir}/gradle/publish.gradle"
apply from: "${rootProject.projectDir}/gradle/sonarqube.gradle"