j2html/gradle/test/junit5.gradle

dependencies {
    testImplementation testLibs.junit.jupiter.api
    testImplementation testLibs.hamcrest
    testRuntimeOnly testLibs.junit.jupiter.engine
    testRuntimeOnly testLibs.junit.jupiter.platform.launcher
}

test {
    useJUnitPlatform()
    failFast = false
    // for mockito
    jvmArgs '--add-modules=jdk.unsupported',
            '--add-exports=jdk.unsupported/sun.reflect=ALL-UNNAMED',
            '--add-opens=jdk.unsupported/sun.reflect=ALL-UNNAMED'

    systemProperty 'java.util.logging.config.file', 'src/test/resources/logging.properties'
    testLogging {
        events 'STARTED', 'PASSED', 'FAILED', 'SKIPPED'
    }
    afterSuite { desc, result ->
        if (!desc.parent) {
            println "\nTest result: ${result.resultType}"
            println "Test summary: ${result.testCount} tests, " +
                    "${result.successfulTestCount} succeeded, " +
                    "${result.failedTestCount} failed, " +
                    "${result.skippedTestCount} skipped"
        }
    }
}