
apply plugin: 'java-library'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
    modularity.inferModulePath.set(true)
    withSourcesJar()
    withJavadocJar()
}

jar {
    manifest {
        attributes('Implementation-Version': project.version)
        attributes('X-Java-Compiler-Version': JavaLanguageVersion.of(21).toString())
    }
}

tasks.withType(JavaCompile) {
    options.fork = true
    options.forkOptions.jvmArgs += [
            '-Duser.language=en',
            '-Duser.country=US',
    ]
    options.compilerArgs += [
            '-Xlint:all',
            '--add-exports=jdk.unsupported/sun.misc=org.xbib.io.netty.jctools',
            '--add-exports=java.base/jdk.internal.misc=org.xbib.io.netty.util'
    ]
    options.encoding = 'UTF-8'
}

tasks.withType(Javadoc) {
    options.addStringOption('Xdoclint:none', '-quiet')
    options.encoding = 'UTF-8'
}
