netty/netty-channel-epoll-native/build.gradle

task nettyEpollLinuxX8664(type: Jar) {
    destinationDirectory.set(project.layout.buildDirectory.dir('libs'))
    archiveBaseName.set(project.name + '-' + project.version)
    archiveExtension.set('jar')
    archiveClassifier.set('linux-x86_64')
    version rootProject.version
    from (project.layout.projectDirectory.dir('src/main/resources')) {
        include 'META-INF/native/libnetty_transport_native_epoll_x86_64.so'
    }
}
assemble.dependsOn(nettyEpollLinuxX8664)

configurations {
    'linux-x86_64' {
        canBeConsumed = true
        canBeResolved = false
        attributes {
            attribute(Category.CATEGORY_ATTRIBUTE, objects.named(Category, Category.LIBRARY))
            attribute(Usage.USAGE_ATTRIBUTE, objects.named(Usage, Usage.JAVA_RUNTIME))
            attribute(Bundling.BUNDLING_ATTRIBUTE, objects.named(Bundling, Bundling.EXTERNAL))
            attribute(TargetJvmVersion.TARGET_JVM_VERSION_ATTRIBUTE, JavaVersion.current().majorVersion.toInteger())
            attribute(LibraryElements.LIBRARY_ELEMENTS_ATTRIBUTE, objects.named(LibraryElements, 'linux-x86_64'))
        }
    }
}

artifacts {
    'linux-x86_64'(nettyEpollLinuxX8664)
}

publishing {
    publications {
        publishNettyEpollLinuxX8664(MavenPublication) {
            groupId rootProject.group
            artifactId project.name
            version rootProject.version
            artifact nettyEpollLinuxX8664
            pom {
                artifactId = project.name
                name = project.name
                version = project.version
                description = rootProject.ext.description
                url = rootProject.ext.url
                inceptionYear = rootProject.ext.inceptionYear
                packaging = 'jar'
                organization {
                    name = rootProject.ext.organizationName
                    url = rootProject.ext.organizationUrl
                }
                developers {
                    developer {
                        id = 'jprante'
                        name = 'Jörg Prante'
                        email = 'joergprante@gmail.com'
                        url = 'https://xbib.org/joerg'
                    }
                }
                scm {
                    url = rootProject.ext.scmUrl
                    connection = rootProject.ext.scmConnection
                    developerConnection = rootProject.ext.scmDeveloperConnection
                }
                issueManagement {
                    system = rootProject.ext.issueManagementSystem
                    url = rootProject.ext.issueManagementUrl
                }
                licenses {
                    license {
                        name = rootProject.ext.licenseName
                        url = rootProject.ext.licenseUrl
                        distribution = 'repo'
                    }
                }
            }
        }
    }
}