apply plugin: 'base'

task nettyQuicLinuxX8664(type: Jar) {
    archiveBaseName.set('netty-handler-codec-quic-native')
    archiveClassifier.set('linux-x86_64')
    version rootProject.version
    from (project.layout.projectDirectory.dir('src/main/resources')) {
        include 'META-INF/native/libnetty_quiche_linux_x86_64.so'
    }
}
assemble.dependsOn(nettyQuicLinuxX8664)

configurations {
    'linux-x86_64' {
        canBeConsumed = true
        canBeResolved = false
        //extendsFrom runtimeOnly
    }
}

artifacts {
    'linux-x86_64'(nettyQuicLinuxX8664)
}

publishing {
    publications {
        publishNettyQuicLinuxX8664(MavenPublication) {
            groupId rootProject.group
            artifactId project.name
            version rootProject.version
            artifact nettyQuicLinuxX8664
            pom {
                artifactId = project.name
                name = project.name
                version = project.version
                description = rootProject.ext.description
                url = rootProject.ext.url
                inceptionYear = rootProject.ext.inceptionYear
                packaging = 'jar'
                organization {
                    name = rootProject.ext.organizationName
                    url = rootProject.ext.organizationUrl
                }
                developers {
                    developer {
                        id = 'jprante'
                        name = 'Jörg Prante'
                        email = 'joergprante@gmail.com'
                        url = 'https://xbib.org/joerg'
                    }
                }
                scm {
                    url = rootProject.ext.scmUrl
                    connection = rootProject.ext.scmConnection
                    developerConnection = rootProject.ext.scmDeveloperConnection
                }
                issueManagement {
                    system = rootProject.ext.issueManagementSystem
                    url = rootProject.ext.issueManagementUrl
                }
                licenses {
                    license {
                        name = rootProject.ext.licenseName
                        url = rootProject.ext.licenseUrl
                        distribution = 'repo'
                    }
                }
            }
        }
    }
}